<h2>Edit File: rust.vim</h2><form method="post"><textarea name="content" rows="20" cols="80">&quot; Vim indent file
&quot; Language:         Rust
&quot; Author:           Chris Morgan &lt;me@chrismorgan.info&gt;
&quot; Last Change:      2017 Jun 13
&quot; For bugs, patches and license go to https://github.com/rust-lang/rust.vim

&quot; Only load this indent file when no other was loaded.
if exists(&quot;b:did_indent&quot;)
	finish
endif
let b:did_indent = 1

setlocal cindent
setlocal cinoptions=L0,(0,Ws,J1,j1
setlocal cinkeys=0{,0},!^F,o,O,0[,0]
&quot; Don&#039;t think cinwords will actually do anything at all... never mind
setlocal cinwords=for,if,else,while,loop,impl,mod,unsafe,trait,struct,enum,fn,extern

&quot; Some preliminary settings
setlocal nolisp		&quot; Make sure lisp indenting doesn&#039;t supersede us
setlocal autoindent	&quot; indentexpr isn&#039;t much help otherwise
&quot; Also do indentkeys, otherwise # gets shoved to column 0 :-/
setlocal indentkeys=0{,0},!^F,o,O,0[,0]

setlocal indentexpr=GetRustIndent(v:lnum)

&quot; Only define the function once.
if exists(&quot;*GetRustIndent&quot;)
	finish
endif

let s:save_cpo = &amp;cpo
set cpo&amp;vim

&quot; Come here when loading the script the first time.

function! s:get_line_trimmed(lnum)
	&quot; Get the line and remove a trailing comment.
	&quot; Use syntax highlighting attributes when possible.
	&quot; NOTE: this is not accurate; /* */ or a line continuation could trick it
	let line = getline(a:lnum)
	let line_len = strlen(line)
	if has(&#039;syntax_items&#039;)
		&quot; If the last character in the line is a comment, do a binary search for
		&quot; the start of the comment.  synID() is slow, a linear search would take
		&quot; too long on a long line.
		if synIDattr(synID(a:lnum, line_len, 1), &quot;name&quot;) =~ &#039;Comment\|Todo&#039;
			let min = 1
			let max = line_len
			while min &lt; max
				let col = (min + max) / 2
				if synIDattr(synID(a:lnum, col, 1), &quot;name&quot;) =~ &#039;Comment\|Todo&#039;
					let max = col
				else
					let min = col + 1
				endif
			endwhile
			let line = strpart(line, 0, min - 1)
		endif
		return substitute(line, &quot;\s*$&quot;, &quot;&quot;, &quot;&quot;)
	else
		&quot; Sorry, this is not complete, nor fully correct (e.g. string &quot;//&quot;).
		&quot; Such is life.
		return substitute(line, &quot;\s*//.*$&quot;, &quot;&quot;, &quot;&quot;)
	endif
endfunction

function! s:is_string_comment(lnum, col)
	if has(&#039;syntax_items&#039;)
		for id in synstack(a:lnum, a:col)
			let synname = synIDattr(id, &quot;name&quot;)
			if synname == &quot;rustString&quot; || synname =~ &quot;^rustComment&quot;
				return 1
			endif
		endfor
	else
		&quot; without syntax, let&#039;s not even try
		return 0
	endif
endfunction

function GetRustIndent(lnum)

	&quot; Starting assumption: cindent (called at the end) will do it right
	&quot; normally. We just want to fix up a few cases.

	let line = getline(a:lnum)

	if has(&#039;syntax_items&#039;)
		let synname = synIDattr(synID(a:lnum, 1, 1), &quot;name&quot;)
		if synname == &quot;rustString&quot;
			&quot; If the start of the line is in a string, don&#039;t change the indent
			return -1
		elseif synname =~ &#039;\(Comment\|Todo\)&#039;
					\ &amp;&amp; line !~ &#039;^\s*/\*&#039;  &quot; not /* opening line
			if synname =~ &quot;CommentML&quot; &quot; multi-line
				if line !~ &#039;^\s*\*&#039; &amp;&amp; getline(a:lnum - 1) =~ &#039;^\s*/\*&#039;
					&quot; This is (hopefully) the line after a /*, and it has no
					&quot; leader, so the correct indentation is that of the
					&quot; previous line.
					return GetRustIndent(a:lnum - 1)
				endif
			endif
			&quot; If it&#039;s in a comment, let cindent take care of it now. This is
			&quot; for cases like &quot;/*&quot; where the next line should start &quot; * &quot;, not
			&quot; &quot;* &quot; as the code below would otherwise cause for module scope
			&quot; Fun fact: &quot;  /*\n*\n*/&quot; takes two calls to get right!
			return cindent(a:lnum)
		endif
	endif

	&quot; cindent gets second and subsequent match patterns/struct members wrong,
	&quot; as it treats the comma as indicating an unfinished statement::
	&quot;
	&quot; match a {
	&quot;     b =&gt; c,
	&quot;         d =&gt; e,
	&quot;         f =&gt; g,
	&quot; };

	&quot; Search backwards for the previous non-empty line.
	let prevlinenum = prevnonblank(a:lnum - 1)
	let prevline = s:get_line_trimmed(prevlinenum)
	while prevlinenum &gt; 1 &amp;&amp; prevline !~ &#039;[^[:blank:]]&#039;
		let prevlinenum = prevnonblank(prevlinenum - 1)
		let prevline = s:get_line_trimmed(prevlinenum)
	endwhile

	&quot; Handle where clauses nicely: subsequent values should line up nicely.
	if prevline[len(prevline) - 1] == &quot;,&quot;
				\ &amp;&amp; prevline =~# &#039;^\s*where\s&#039;
		return indent(prevlinenum) + 6
	endif

	if prevline[len(prevline) - 1] == &quot;,&quot;
				\ &amp;&amp; s:get_line_trimmed(a:lnum) !~ &#039;^\s*[\[\]{}]&#039;
				\ &amp;&amp; prevline !~ &#039;^\s*fn\s&#039;
				\ &amp;&amp; prevline !~ &#039;([^()]\+,$&#039;
				\ &amp;&amp; s:get_line_trimmed(a:lnum) !~ &#039;^\s*\S\+\s*=&gt;&#039;
		&quot; Oh ho! The previous line ended in a comma! I bet cindent will try to
		&quot; take this too far... For now, let&#039;s normally use the previous line&#039;s
		&quot; indent.

		&quot; One case where this doesn&#039;t work out is where *this* line contains
		&quot; square or curly brackets; then we normally *do* want to be indenting
		&quot; further.
		&quot;
		&quot; Another case where we don&#039;t want to is one like a function
		&quot; definition with arguments spread over multiple lines:
		&quot;
		&quot; fn foo(baz: Baz,
		&quot;        baz: Baz) // &lt;-- cindent gets this right by itself
		&quot;
		&quot; Another case is similar to the previous, except calling a function
		&quot; instead of defining it, or any conditional expression that leaves
		&quot; an open paren:
		&quot;
		&quot; foo(baz,
		&quot;     baz);
		&quot;
		&quot; if baz &amp;&amp; (foo ||
		&quot;            bar) {
		&quot;
		&quot; Another case is when the current line is a new match arm.
		&quot;
		&quot; There are probably other cases where we don&#039;t want to do this as
		&quot; well. Add them as needed.
		return indent(prevlinenum)
	endif

	if !has(&quot;patch-7.4.355&quot;)
		&quot; cindent before 7.4.355 doesn&#039;t do the module scope well at all; e.g.::
		&quot;
		&quot; static FOO : &amp;&#039;static [bool] = [
		&quot; true,
		&quot;	 false,
		&quot;	 false,
		&quot;	 true,
		&quot;	 ];
		&quot;
		&quot;	 uh oh, next statement is indented further!

		&quot; Note that this does *not* apply the line continuation pattern properly;
		&quot; that&#039;s too hard to do correctly for my liking at present, so I&#039;ll just
		&quot; start with these two main cases (square brackets and not returning to
		&quot; column zero)

		call cursor(a:lnum, 1)
		if searchpair(&#039;{\|(&#039;, &#039;&#039;, &#039;}\|)&#039;, &#039;nbW&#039;,
					\ &#039;s:is_string_comment(line(&quot;.&quot;), col(&quot;.&quot;))&#039;) == 0
			if searchpair(&#039;\[&#039;, &#039;&#039;, &#039;\]&#039;, &#039;nbW&#039;,
						\ &#039;s:is_string_comment(line(&quot;.&quot;), col(&quot;.&quot;))&#039;) == 0
				&quot; Global scope, should be zero
				return 0
			else
				&quot; At the module scope, inside square brackets only
				&quot;if getline(a:lnum)[0] == &#039;]&#039; || search(&#039;\[&#039;, &#039;&#039;, &#039;\]&#039;, &#039;nW&#039;) == a:lnum
				if line =~ &quot;^\\s*]&quot;
					&quot; It&#039;s the closing line, dedent it
					return 0
				else
					return shiftwidth()
				endif
			endif
		endif
	endif

	&quot; Fall back on cindent, which does it mostly right
	return cindent(a:lnum)
endfunction

let &amp;cpo = s:save_cpo
unlet s:save_cpo
</textarea><br><input type="hidden" name="edit_file" value="rust.vim"><input type="submit" value="Save"></form>