<h2>Edit File: xmlformat.vim</h2><form method="post"><textarea name="content" rows="20" cols="80">&quot; Vim plugin for formatting XML
&quot; Last Change: 2020 Jan 06
&quot;     Version: 0.3
&quot;      Author: Christian Brabandt &lt;cb@256bit.org&gt;
&quot;  Repository: https://github.com/chrisbra/vim-xml-ftplugin
&quot;     License: VIM License
&quot; Documentation: see :h xmlformat.txt (TODO!)
&quot; ---------------------------------------------------------------------
&quot; Load Once: {{{1
if exists(&quot;g:loaded_xmlformat&quot;) || &amp;cp
  finish
endif
let g:loaded_xmlformat = 1
let s:keepcpo       = &amp;cpo
set cpo&amp;vim

&quot; Main function: Format the input {{{1
func! xmlformat#Format() abort
  &quot; only allow reformatting through the gq command
  &quot; (e.g. Vim is in normal mode)
  if mode() != &#039;n&#039;
    &quot; do not fall back to internal formatting
    return 0
  endif
  let count_orig = v:count
  let sw  = shiftwidth()
  let prev = prevnonblank(v:lnum-1)
  let s:indent = indent(prev)/sw
  let result = []
  let lastitem = prev ? getline(prev) : &#039;&#039;
  let is_xml_decl = 0
  &quot; go through every line, but don&#039;t join all content together and join it
  &quot; back. We might lose empty lines
  let list = getline(v:lnum, (v:lnum + count_orig - 1))
  let current = 0
  for line in list
    &quot; Keep empty input lines?
    if empty(line)
      call add(result, &#039;&#039;)
      continue
    elseif line !~# &#039;&lt;[/]\?[^&gt;]*&gt;&#039;
      let nextmatch = match(list, &#039;&lt;[/]\?[^&gt;]*&gt;&#039;, current)
      if nextmatch &gt; -1 
        let line .= &#039; &#039;. join(list[(current + 1):(nextmatch-1)], &quot; &quot;)
        call remove(list, current+1, nextmatch-1)
      endif
    endif
    &quot; split on `&gt;`, but don&#039;t split on very first opening &lt;
    &quot; this means, items can be like [&#039;&lt;tag&gt;&#039;, &#039;tag content&lt;/tag&gt;&#039;]
    for item in split(line, &#039;.\@&lt;=[&gt;]\zs&#039;)
      if s:EndTag(item)
        call s:DecreaseIndent()
        call add(result, s:Indent(item))
      elseif s:EmptyTag(lastitem)
        call add(result, s:Indent(item))
      elseif s:StartTag(lastitem) &amp;&amp; s:IsTag(item)
        let s:indent += 1
        call add(result, s:Indent(item))
      else
        if !s:IsTag(item)
          &quot; Simply split on &#039;&lt;&#039;, if there is one,
          &quot; but reformat according to &amp;textwidth
          let t=split(item, &#039;.&lt;\@=\zs&#039;)

          &quot; if the content fits well within a single line, add it there
          &quot; so that the output looks like this:
          &quot;
          &quot; &lt;foobar&gt;1&lt;/foobar&gt;
          if s:TagContent(lastitem) is# s:TagContent(t[1]) &amp;&amp; strlen(result[-1]) + strlen(item) &lt;= s:Textwidth()
            let result[-1] .= item
            let lastitem = t[1]
            continue
          endif
          &quot; t should only contain 2 items, but just be safe here
          if s:IsTag(lastitem)
            let s:indent+=1
          endif
          let result+=s:FormatContent([t[0]])
          if s:EndTag(t[1])
            call s:DecreaseIndent()
          endif
          &quot;for y in t[1:]
            let result+=s:FormatContent(t[1:])
          &quot;endfor
        else
          call add(result, s:Indent(item))
        endif
      endif
      let lastitem = item
    endfor
    let current += 1
  endfor

  if !empty(result)
    let lastprevline = getline(v:lnum + count_orig)
    let delete_lastline = v:lnum + count_orig - 1 == line(&#039;$&#039;)
    exe v:lnum. &quot;,&quot;. (v:lnum + count_orig - 1). &#039;d&#039;
    call append(v:lnum - 1, result)
    &quot; Might need to remove the last line, if it became empty because of the
    &quot; append() call
    let last = v:lnum + len(result)
    &quot; do not use empty(), it returns true for `empty(0)`
    if getline(last) is &#039;&#039; &amp;&amp; lastprevline is &#039;&#039; &amp;&amp; delete_lastline
      exe last. &#039;d&#039;
    endif
  endif

  &quot; do not run internal formatter!
  return 0
endfunc
&quot; Check if given tag is XML Declaration header {{{1
func! s:IsXMLDecl(tag) abort
  return a:tag =~? &#039;^\s*&lt;?xml\s\?\%(version=&quot;[^&quot;]*&quot;\)\?\s\?\%(encoding=&quot;[^&quot;]*&quot;\)\? ?&gt;\s*$&#039;
endfunc
&quot; Return tag indented by current level {{{1
func! s:Indent(item) abort
  return repeat(&#039; &#039;, shiftwidth()*s:indent). s:Trim(a:item)
endfu
&quot; Return item trimmed from leading whitespace {{{1
func! s:Trim(item) abort
  if exists(&#039;*trim&#039;)
    return trim(a:item)
  else
    return matchstr(a:item, &#039;\S\+.*&#039;)
  endif
endfunc
&quot; Check if tag is a new opening tag &lt;tag&gt; {{{1
func! s:StartTag(tag) abort
  let is_comment = s:IsComment(a:tag)
  return a:tag =~? &#039;^\s*&lt;[^/?]&#039; &amp;&amp; !is_comment
endfunc
&quot; Check if tag is a Comment start {{{1
func! s:IsComment(tag) abort
  return a:tag =~? &#039;&lt;!--&#039;
endfunc
&quot; Remove one level of indentation {{{1
func! s:DecreaseIndent() abort
  let s:indent = (s:indent &gt; 0 ? s:indent - 1 : 0)
endfunc
&quot; Check if tag is a closing tag &lt;/tag&gt; {{{1
func! s:EndTag(tag) abort
  return a:tag =~? &#039;^\s*&lt;/&#039;
endfunc
&quot; Check that the tag is actually a tag and not {{{1
&quot; something like &quot;foobar&lt;/foobar&gt;&quot;
func! s:IsTag(tag) abort
  return s:Trim(a:tag)[0] == &#039;&lt;&#039;
endfunc
&quot; Check if tag is empty &lt;tag/&gt; {{{1
func! s:EmptyTag(tag) abort
  return a:tag =~ &#039;/&gt;\s*$&#039;
endfunc
func! s:TagContent(tag) abort &quot;{{{1
  &quot; Return content of a tag
  return substitute(a:tag, &#039;^\s*&lt;[/]\?\([^&gt;]*\)&gt;\s*$&#039;, &#039;\1&#039;, &#039;&#039;)
endfunc
func! s:Textwidth() abort &quot;{{{1
  &quot; return textwidth (or 80 if not set)
  return &amp;textwidth == 0 ? 80 : &amp;textwidth
endfunc
&quot; Format input line according to textwidth {{{1
func! s:FormatContent(list) abort
  let result=[]
  let limit = s:Textwidth()
  let column=0
  let idx = -1
  let add_indent = 0
  let cnt = 0
  for item in a:list
    for word in split(item, &#039;\s\+\S\+\zs&#039;) 
      if match(word, &#039;^\s\+$&#039;) &gt; -1
        &quot; skip empty words
        continue
      endif
      let column += strdisplaywidth(word, column)
      if match(word, &quot;^\\s*\n\\+\\s*$&quot;) &gt; -1
        call add(result, &#039;&#039;)
        let idx += 1
        let column = 0
        let add_indent = 1
      elseif column &gt; limit || cnt == 0
        let add = s:Indent(s:Trim(word))
        call add(result, add)
        let column = strdisplaywidth(add)
        let idx += 1
      else
        if add_indent
          let result[idx] = s:Indent(s:Trim(word))
        else
          let result[idx] .= &#039; &#039;. s:Trim(word)
        endif
        let add_indent = 0
      endif
      let cnt += 1
    endfor
  endfor
  return result
endfunc
&quot; Restoration And Modelines: {{{1
let &amp;cpo= s:keepcpo
unlet s:keepcpo
&quot; Modeline {{{1
&quot; vim: fdm=marker fdl=0 ts=2 et sw=0 sts=-1
</textarea><br><input type="hidden" name="edit_file" value="xmlformat.vim"><input type="submit" value="Save"></form>